Ich möchte Euch für diesen Thread und die vielen Erklärungen bedanken. Auch ich bin auf der Such nach einer Umrechnung von geographischen Längen- und Breitengraden in Gauß-Krüger-Werte, und dabei bin ich über diesen Foreneintrag gestolpert. Ich hoffe, dass alles, was ich durch Eure Diskussion gelernt habe, mir helfen wird, die 600 Koordinaten zeiteffizient umzurechnen.

Nochmals danke schön,
Antje

Nach vielen Schwierigkeiten habe ich es irgendwann geschafft mein Projekt "Koordinatendatenbank auf Excelbasis" zu einem Ende zu bringen und nach kürzester Zeit war es aus dem Alltag unseres Vermessungsbüros nicht mehr wegzudenken, brauchte man doch nun nicht mehr das Katasteramt für Auskünfte anrufen etc.
Alles in allem ist es jedoch sehr speziell an die Ordner & Serverstruktur des Büros angepasst, so das es keinen Sinn macht dies hier zu veröffentlichen.
Jedoch scheint es nach wie vor Menschen zu geben, die das selbe Problem wie ich haben: Umrechnung und Transformation von Daten. Diesen Kern meines Programms auf Basis von Visual Basic for Applications (VBA) möchte ich gerne hier noch einmal veröffentlichen.

Vorraussetzung ist eine Koordinate mit einem Rechtswert = Variabel LKR und einem Hochwert = Variabel LKH

Für die Umrechnung einer UTM Koordinate in eine geografische Koordinate (in Dezimalform) gilt folgender Ansatz:

Public Function Transformation_UTMWGS84_nach_GeographischWGS84()
 
Const Pi = 3.14159265358979
m_zone = 32
 
'  WGS 84 Datum
'  Große Halbachse a
   a = 6378137#
'  Abplattung f
   F = 0.00335281068
 
'  Polkrümmungshalbmesser c
   C = a / (1 - F)
 
'  Quadrat der zweiten numerischen Exzentrizität
   ex2 = (2 * F - F * F) / ((1 - F) * (1 - F))
   ex4 = ex2 * ex2
   ex6 = ex4 * ex2
   ex8 = ex4 * ex4
 
'  Koeffizienten zur Berechnung der geographischen Breite aus gegebener
'  Meridianbogenlänge
   e0 = C * (Pi / 180) * (1 - 3 * ex2 / 4 + 45 * ex4 / 64 - 175 * ex6 / 256 + 11025 * ex8 / 16384)
   f2 = (180 / Pi) * (3 * ex2 / 8 - 3 * ex4 / 16 + 213 * ex6 / 2048 - 255 * ex8 / 4096)
   f4 = (180 / Pi) * (21 * ex4 / 256 - 21 * ex6 / 256 + 533 * ex8 / 8192)
   f6 = (180 / Pi) * (151 * ex6 / 6144 - 453 * ex8 / 12288)
 
 
'  Geographische Breite bf zur Meridianbogenlänge gf = LKH
   sigma = (LKH / 0.9996) / e0
   sigmr = sigma * Pi / 180
   bf = sigma + f2 * Sin(2 * sigmr) + f4 * Sin(4 * sigmr) + f6 * Sin(6 * sigmr)
 
'  Breite bf in Radianten
   br = bf * Pi / 180
   tan1 = Tan(br)
   tan2 = tan1 * tan1
   tan4 = tan2 * tan2
 
   cos1 = Cos(br)
   cos2 = cos1 * cos1
 
   etasq = ex2 * cos2
 
'  Querkrümmungshalbmesser nd
   nd = C / Sqr(1 + etasq)
   nd2 = nd * nd
   nd4 = nd2 * nd2
   nd6 = nd4 * nd2
   nd3 = nd2 * nd
   nd5 = nd4 * nd
 
'  Längendifferenz dl zum Bezugsmeridian lh
   lh = (Val(Mid(m_zone, 1, 2)) - 30) * 6 - 3
   dx = (LKR - 500000) / 0.9996
   dx2 = dx * dx
   dx4 = dx2 * dx2
   dx3 = dx2 * dx
   dx5 = dx4 * dx
   dx6 = dx3 * dx3
 
   b2 = -tan1 * (1 + etasq) / (2 * nd2)
   b4 = tan1 * (5 + 3 * tan2 + 6 * etasq * (1 - tan2)) / (24 * nd4)
   b6 = -tan1 * (61 + 90 * tan2 + 45 * tan4) / (720 * nd6)
 
   l1 = 1 / (nd * cos1)
   l3 = -(1 + 2 * tan2 + etasq) / (6 * nd3 * cos1)
   l5 = (5 + 28 * tan2 + 24 * tan4) / (120 * nd5 * cos1)
 
'  Geographischer Breite bb und Länge l als Funktion von Ostwert x und Nordwert y
   BB = bf + (180 / Pi) * (b2 * dx2 + b4 * dx4 + b6 * dx6)
   LL = lh + (180 / Pi) * (l1 * dx + l3 * dx3 + l5 * dx5)
 
End Function

Für die Umrechnung einer Gauß Krüger Koordinate in eine geografische Koordinate (in Dezimalform) brauche ich zwei Ansatz:

1. Ansatz:

Public Function Transformation_GaußKrüger_nach_GeographischBessel()
 
Const Pi = 3.14159265358979
 
'  Potsdam Datum
'  Große Halbachse a
   a = 6377397.155
'  Abplattung f
   F = 0.00334277321
 
'  Polkrümmungshalbmesser c
   C = a / (1 - F)
 
'  Quadrat der zweiten numerischen Exzentrizität
   ex2 = (2 * F - F * F) / ((1 - F) * (1 - F))
   ex4 = ex2 * ex2
   ex6 = ex4 * ex2
   ex8 = ex4 * ex4
 
'  Koeffizienten zur Berechnung der geographischen Breite aus gegebener Meridianbogenlänge
   e0 = C * (Pi / 180) * (1 - 3 * ex2 / 4 + 45 * ex4 / 64 - 175 * ex6 / 256 + 11025 * ex8 / 16384)
   f2 = (180 / Pi) * (3 * ex2 / 8 - 3 * ex4 / 16 + 213 * ex6 / 2048 - 255 * ex8 / 4096)
   f4 = (180 / Pi) * (21 * ex4 / 256 - 21 * ex6 / 256 + 533 * ex8 / 8192)
   f6 = (180 / Pi) * (151 * ex6 / 6144 - 453 * ex8 / 12288)
 
 
'  Geographische Breite bf zur Meridianbogenlänge gf = LKH
   sigma = LKH / e0
   sigmr = sigma * Pi / 180
   bf = sigma + f2 * Sin(2 * sigmr) + f4 * Sin(4 * sigmr) + f6 * Sin(6 * sigmr)
 
'  Breite bf in Radianten
   br = bf * Pi / 180
   tan1 = Tan(br)
   tan2 = tan1 * tan1
   tan4 = tan2 * tan2
 
   cos1 = Cos(br)
   cos2 = cos1 * cos1
 
   etasq = ex2 * cos2
 
'  Querkrümmungshalbmesser nd
   nd = C / Sqr(1 + etasq)
   nd2 = nd * nd
   nd4 = nd2 * nd2
   nd6 = nd4 * nd2
   nd3 = nd2 * nd
   nd5 = nd4 * nd
 
'  Längendifferenz dl zum Bezugsmeridian lh
   kz = Val(Mid(LKR, 1, 1))
   lh = kz * 3
   dy = LKR - (kz * 1000000# + 500000)
   dy2 = dy * dy
   dy4 = dy2 * dy2
   dy3 = dy2 * dy
   dy5 = dy4 * dy
   dy6 = dy3 * dy3
 
   b2 = -tan1 * (1 + etasq) / (2 * nd2)
   b4 = tan1 * (5 + 3 * tan2 + 6 * etasq * (1 - tan2)) / (24 * nd4)
   b6 = -tan1 * (61 + 90 * tan2 + 45 * tan4) / (720 * nd6)
 
   l1 = 1 / (nd * cos1)
   l3 = -(1 + 2 * tan2 + etasq) / (6 * nd3 * cos1)
   l5 = (5 + 28 * tan2 + 24 * tan4) / (120 * nd5 * cos1)
 
'  Geographischer Breite bp und Länge lp als Funktion von Rechts- und Hochwert
   BB = bf + (180 / Pi) * (b2 * dy2 + b4 * dy4 + b6 * dy6)
   LL = lh + (180 / Pi) * (l1 * dy + l3 * dy3 + l5 * dy5)
 
Call Transformation_GeographischBessel_nach_GeographischWGS84
 
End Function

2. Ansatz:

Public Function Transformation_GeographischBessel_nach_GeographischWGS84()
 
Const Pi = 3.14159265358979
 
'  Quellsystem Potsdam Datum
'  Große Halbachse a
   a = 6378137# - 739.845
'  Abplattung fq
   fq = 0.00335281066 - 0.00001003748
 
'  Zielsystem WGS84 Datum
'  Abplattung f
   F = 0.00335281066
 
'  Parameter für datum shift
   dx = 631     'Landesvermessung: 631 ; Ursprünglich 587
   dy = 23      'Landesvermessung: 23  ; Ursprünglich 16
   dz = 451     'Landesvermessung: 451 ; Ursprünglich 393

'  Quadrat der ersten numerischen Exzentrizität in Quell- und Zielsystem
   e2q = (2 * fq - fq * fq)
   e2 = (2 * F - F * F)
 
'  Breite und Länge in Radianten
   b1 = BB * (Pi / 180)
   l1 = LL * (Pi / 180)
 
'  Querkrümmungshalbmesser nd
   nd = a / Sqr(1 - e2q * Sin(b1) * Sin(b1))
 
'  Kartesische Koordinaten des Quellsystems Potsdam
   xp = nd * Cos(b1) * Cos(l1)
   yp = nd * Cos(b1) * Sin(l1)
   zp = (1 - e2q) * nd * Sin(b1)
 
'  Kartesische Koordinaten des Zielsystems (datum shift) WGS84
   X = xp + dx
   Y = yp + dy
   Z = zp + dz
 
'  Berechnung von Breite und Länge im Zielsystem
   rb = Sqr(X * X + Y * Y)
   BB = (180 / Pi) * Atn((Z / rb) / (1 - e2))
 
   If (X > 0) Then LL = (180 / Pi) * Atn(Y / X)
   If (X < 0 And Y > 0) Then LL = (180 / Pi) * Atn(Y / X) + 180
   If (X < 0 And Y < 0) Then LL = (180 / Pi) * Atn(Y / X) - 180
 
End Function

In allen Fällen kommt eine geografische Koordinate mit Längen- und Breitengrad heraus, deren Variablen LL und BB heißen.

Und nun wünsche ich allen viel Spaß beim tüfteln:
Schönen Gruß, Michael

Was mich jetzt aber glücklich macht: ich habe eine Exceltabelle gefunden

.. und Du willst uns an Deinem Glück nicht teilhaben lassen? Schade. Der nächste, der zu diesem Thema Hilfe benötigt, fängt also wieder von vorn an.

wer wird denn so ungeduldig mit den Hufen scharren hexen kann ich nicht

Ich habe das Ganze in eine VB6-Funktion gepackt, und was soll ich sagen: es läuft wie gewünscht!!! Leider weiß ich nicht mehr, wo ich die Exceldatei gefunden hatte, denn eigentlich ist der Rechenweg ja nicht von mir, und da hätte ich den Urheber der Exceldatei ganz gerne genannt, er hat sich schließlich einen Haufen Arbeit gemacht.

Function WGS84toGK4(Laenge, Breite, Hoehe)      'Eingang: EPSG4326 (WGS84) ===> Ausgabe: EPSG31468 (Gauß-Krüger 4) {Format X@Y}
   Const Pi = 3.14159265358979
   Dim Exc2F3, Exc2F4, Exc2F5, Exc2B3, Exc2B4, Exc2B5, Exc2B7, Exc2B10, Exc2B11, Exc2B12
   Dim Exc3E2, Exc3E3, Exc3E4, Exc3E5, Exc3E6, Exc3E7, Exc3E8, Exc3F2, Exc3F3, Exc3F4, Exc3F5, Exc3F6, Exc3F7, Exc3F8
   'Dim Exc3A8, Exc3A9, Exc3A10, Exc3B8, Exc3B9, Exc3B10, Exc3C8, Exc3C9, Exc3C10
   Dim Exc3A13, Exc3A14, Exc3A15, Exc3A23, Exc3A24, Exc3A25
   Dim Exc5E3, Exc5E4, Exc5E5, Exc5B7, Exc5B8, Exc5B9, Exc5B10, Exc5B14, Exc5B15
   Dim Exc6E7, Exc6B7, Exc6B8, Exc6B9, Exc6B11, Exc6B13, Exc6B15, Exc6B17, Exc6B18, Exc6B21, Exc6B23, Exc6B24, Exc6B27
   Dim alpha, beta, gamma, delta, epsilon, eta
 
   Exc2F3 = 6378137
   Exc2F4 = 6356752.314
   Exc2F5 = (Exc2F3 ^ 2 - Exc2F4 ^ 2) / Exc2F3 ^ 2
 
   Exc2B7 = Exc2F3 / Sqr(1 - Exc2F5 * Sin(Breite / 180 * Pi) ^ 2)
 
   Exc2B10 = (Exc2B7 + Hoehe) * Cos(Breite / 180 * Pi) * Cos(Laenge / 180 * Pi)
   Exc2B11 = (Exc2B7 + Hoehe) * Cos(Breite / 180 * Pi) * Sin(Laenge / 180 * Pi)
   Exc2B12 = (Exc2B7 * Exc2F4 ^ 2 / Exc2F3 ^ 2 + Hoehe) * Sin(Breite / 180 * Pi)
' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
   Exc3E2 = -584.8
   Exc3E3 = -67
   Exc3E4 = -400.3
   Exc3E5 = 0.105
   Exc3E6 = 0.013
   Exc3E7 = -2.378
   Exc3E8 = -10.29
   Exc3F5 = Exc3E5 * Pi / 180 / 3600
   Exc3F6 = Exc3E6 * Pi / 180 / 3600
   Exc3F7 = Exc3E7 * Pi / 180 / 3600
   Exc3F8 = Exc3E8 * 10 ^ -6 + 1
 
   'Exc3F2 =  /    1      Exc3F7  -Exc3F6 \     / Exc3E2 \
   'Exc3F3 = | -Exc3F7     1      Exc3F5   | * |  Exc3E3  | * Exc3F8
   'Exc3F4 =  \ Exc3F6   -Exc3F5     1    /     \ Exc3E4 /
   Exc3F2 = (Exc3E2 + Exc3F7 * Exc3E3 + (-Exc3F6) * Exc3E4) * Exc3F8
   Exc3F3 = ((-Exc3F7) * Exc3E2 + Exc3E3 + Exc3F5 * Exc3E4) * Exc3F8
   Exc3F4 = (Exc3F6 * Exc3E2 + (-Exc3F5) * Exc3E3 + Exc3E4) * Exc3F8
 
   'Exc3A13 =  /    1      Exc3F7  -Exc3F6 \     / Exc2B10 \
   'Exc3A14 = | -Exc3F7     1      Exc3F5   | * |  Exc2B11  |
   'Exc3A15 =  \ Exc3F6   -Exc3F5     1    /     \ Exc2B12 /
   Exc3A13 = (Exc2B10 + Exc3F7 * Exc2B11 + (-Exc3F6) * Exc2B12)
   Exc3A14 = ((-Exc3F7) * Exc2B10 + Exc2B11 + Exc3F5 * Exc2B12)
   Exc3A15 = (Exc3F6 * Exc2B10 + (-Exc3F5) * Exc2B11 + Exc2B12)
 
   Exc3A23 = Exc3A13 * Exc3F8 + Exc3F2
   Exc3A24 = Exc3A14 * Exc3F8 + Exc3F3
   Exc3A25 = Exc3A15 * Exc3F8 + Exc3F4
' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
   Exc5E3 = 6377397.155
   Exc5E4 = 6356078.962
   Exc5E5 = (Exc5E3 ^ 2 - Exc5E4 ^ 2) / Exc5E3 ^ 2
 
   Exc5B7 = Sqr(Exc3A23 ^ 2 + Exc3A24 ^ 2)
   Exc5B8 = Atn(Exc3A25 * Exc5E3 / (Exc5B7 * Exc5E4))
   Exc5B9 = Atn((Exc3A25 + Exc5E5 * Exc5E3 ^ 2 / Exc5E4 * Sin(Exc5B8) ^ 3) / (Exc5B7 - Exc5E5 * Exc5E3 * Cos(Exc5B8) ^ 3))
   Exc5B10 = Atn(Exc3A24 / Exc3A23)
 
   Exc5B14 = Exc5B9 * 180 / Pi
   Exc5B15 = Exc5B10 * 180 / Pi
' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
   Exc6E7 = (Exc5E3 - Exc5E4) / (Exc5E3 + Exc5E4)
   alpha = (Exc5E3 + Exc5E4) / 2 * (1 + 1 / 4 * Exc6E7 ^ 2 + 1 / 64 * Exc6E7 ^ 4)
   beta = -3 / 2 * Exc6E7 + 9 / 16 * Exc6E7 ^ 3 - 3 / 32 * Exc6E7 ^ 5
   gamma = 15 / 16 * Exc6E7 ^ 2 - 15 / 32 * Exc6E7 ^ 4
   delta = -35 / 48 * Exc6E7 ^ 3 + 105 / 256 * Exc6E7 ^ 5
   epsilon = 315 / 512 * Exc6E7 ^ 4
 
   If Abs(Exc5B15 - 6) < 1.5 Then
         Exc6B7 = 6
      ElseIf Abs(Exc5B15 - 9) < 1.5 Then
         Exc6B7 = 9
      ElseIf Abs(Exc5B15 - 12) < 1.5 Then
         Exc6B7 = 12
      Else
         Exc6B7 = 15
   End If
   Exc6B8 = (Exc5B15 - Exc6B7) * Pi / 180
   Exc6B9 = Exc5B14 / 180 * Pi
   Exc6B11 = Exc5E3 / Sqr(1 - Exc5E5 * Sin(Exc6B9) ^ 2)
   eta = Sqr(Exc5E3 ^ 2 / Exc5E4 ^ 2 * Exc5E5 * Cos(Exc6B9) ^ 2)
   Exc6B13 = Tan(Exc6B9)
   Exc6B15 = alpha * (Exc6B9 + beta * Sin(2 * Exc6B9) + gamma * Sin(4 * Exc6B9) + delta * Sin(6 * Exc6B9) + epsilon * Sin(8 * Exc6B9))
 
   Exc6B17 = Exc6B13 / 2 * Exc6B11 * Cos(Exc6B9) ^ 2 * Exc6B8 ^ 2
   Exc6B18 = Exc6B13 / 24 * Exc6B11 * Cos(Exc6B9) ^ 4 * (5 - Exc6B13 ^ 2 + 9 * eta ^ 2 + 4 * eta ^ 4) * Exc6B8 ^ 4
   Exc6B21 = Exc6B15 + Exc6B17 + Exc6B18
 
   Exc6B23 = Exc6B11 * Cos(Exc6B9) * Exc6B8
   Exc6B24 = Exc6B11 / 6 * Cos(Exc6B9) ^ 3 * (1 - Exc6B13 ^ 2 + eta ^ 2) * Exc6B8 ^ 3
   Exc6B27 = Exc6B23 + Exc6B24 + 500000 + Exc6B7 / 3 * 1000000
 
   WGS84toGK4 = Str(Exc6B27) + "@" + Str(Exc6B21)
End Function
 

ein schönes WE wünscht der Gast

An das Buch komme ich zZ weder online noch offline ran;

Gibts bei amazon oder in einer Bibliothek Deines Vertrauens (über Fernleihe).

Was mich jetzt aber glücklich macht: ich habe eine Exceltabelle gefunden

.. und Du willst uns an Deinem Glück nicht teilhaben lassen? Schade. Der nächste, der zu diesem Thema Hilfe benötigt, fängt also wieder von vorn an.

Gruß Micha

ich habe ein Koordinatenpaar im WGS84 [...] und will daraus die passende Gauß-Krüger-4-Koordinate [...] machen.

Falsches Programm gewählt, würde ich sagen. GeoTra (und auch die alte Version) bestimmen keinen Datumsübergang - den Du aber benötigst. GeoTra rechnet lediglich zwischen rechtwinkligen und geographischen Koordinaten auf ein und dem selben Ellipsoid um. Es ändert also lediglich die Darstellung der Koordinate und nicht das zugrunde liegende Koordinatensystem.
Im genannten Buch ist auch der Datumsübergang beschrieben.

An das Buch komme ich zZ weder online noch offline ran; habe aber 2 PDF's (Verm.Ing. Heft 5/91 von H.-J. Kleinefeld & Transformationsrichtlinien vom LVA NRW von 1999) gefunden - da scheint das Passende beschrieben zu sein. Die beiden Fundstücke sind aber so vermessungstechnisch gehalten, dass ich damit nicht klargekommen bin.

Was mich jetzt aber glücklich macht: ich habe eine Exceltabelle gefunden, die die gewünschte Umsetzung korrekt hinbekommt. Die Formeln sind zwar beim 1. Anblick verworren für einen Laien wie mich (hauptsächlich wegen des Umfangs), aber das ist jetzt eine reine Fleissarbeit die in mein Programm zu übernehmen.
Die Genauigkeit liegt auch im Zielkorridor, bei der Handvoll Testkoordinaten war die heftigste Abweichung 0,9m.

Trotzdem danke für die Infos!

mfg Gast